'Build Date 23.6.2011
'##############
'Getriebe-Script
'##############

'ZF Ecolife 

'(c) 2008-2010 Rüdiger Hülsmann

'Script Version: 1.0
'Omsi release: 1.0

'Needs:
'- engine
'- bremse

'Revision History:
'- Kyle Ortiz           20.06.2011      Script based off of the Ecomat Script 
'- Kyle Ortiz           24.06.2011      Added  topodyn to the script 
'- Kyle Ortiz           07.07.2011      Added different partial throttling techniques to the Script
'- Kyle Ortiz           16.11.2011      Topodyn Updated
'- Kyle Ortiz           11.2.2012       Debugged slippage bug
'- Kyle Ortiz           15.2.2012       Added Retarder downshift

'----------------------
'	Init
'----------------------

{macro:antrieb_init}
	1 (S.L.antrieb_getr_gangwahl) (S.L.antrieb_getr_gangvorwahl)
	1 (S.L.antrieb_getr_aktugang)
	
	0 (S.L.antrieb_kickdown_sense)
	0 (S.L.antrieb_wandler_moment)
{end}

'----------------------
'	Frame
'----------------------

{macro:antrieb_frame}

'Berechnen der Abtriebsdrehzahl
	(L.L.Wheel_RotationSpeed_1_L) (L.L.Wheel_RotationSpeed_1_R) + 2 / (C.L.antrieb_i_achse) * (S.L.antrieb_n_kardanwelle)

'Einlegen der Fahrstufe Loading the gear

	(L.S.GetTime) (L.L.antrieb_getr_gangwahlzeitpunkt) - (C.L.antrieb_gangwahlzeit) >
	(L.L.antrieb_getr_gangvorwahl) (L.L.antrieb_getr_gangwahl) = ! &&
	(L.L.antrieb_failure_general) ! &&
	{if}
			
		(L.L.antrieb_getr_gangwahl) 1 =
		{if}
			(L.L.engine_on) 1 = 
			{if}
				(L.L.engine_n) (S.L.antrieb_rucksoundvol)
				(M.L.input_torque_M_dn_min) (S.L.antrieb_schaltmoment_soll)

				(L.L.antrieb_getr_gangvorwahl) 1 >

				{if}
				
					(L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd6) > 
					
					{if}
						6 (S.L.antrieb_getr_aktugang)
						(T.L.ev_schaltruck)
					{else}
					(L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd5) > 
					
					{if}
						5 (S.L.antrieb_getr_aktugang)
						(T.L.ev_schaltruck)
					{else}
					(L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd4) >
					
					{if}
						4 (S.L.antrieb_getr_aktugang)
						(T.L.ev_schaltruck)
					{else}

					(L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd3) >
					
					{if}
						3 (S.L.antrieb_getr_aktugang)
						(T.L.ev_schaltruck)
					{else}
				       
					
							1 (S.L.antrieb_getr_aktugang)
							0 (S.L.antrieb_gear_engaged_timer)
							(T.L.ev_schaltruck)
											
										{endif}
									{endif}
								{endif}
							{endif}
						
				{else}
					(L.L.velocity) 5 <
					{if}
						1 (S.L.antrieb_getr_aktugang)
						0 (S.L.antrieb_gear_engaged_timer)
						(T.L.ev_schaltruck)
					{endif}
				{endif}
			{endif}
		{endif}	
		(L.L.antrieb_getr_gangvorwahl) (S.L.antrieb_getr_gangwahl)
	{endif}

'Gang rausnehmen, wenn Neutral angefordert

	(L.L.antrieb_getr_gangwahl) 1 =
	{if}
		0 (S.L.antrieb_getr_aktugang)
	{endif}
'Verhindern, dass der Rückwärtsgang oberhalb von 5 km/h eingelegt werden kann

	(L.L.antrieb_getr_gangvorwahl) 0 =
	(L.L.velocity) 5 >= &&
	{if}
		1 (S.L.antrieb_getr_gangwahl)
	{endif}







'Prüfen, ob Gang gewechselt wird - aber nur, wenn Getriebe heil ist:

	(L.L.antrieb_failure_general) !
	{if}
		(M.L.antrieb_getr_chkNxtGear)
	{endif}

'Berechnung des aktuellen Motordrehmoments:

	(M.L.engine_moment)



'Berechnung des dynamischen Schaltmoments
(L.L.M_Wheel) (L.L.antrieb_getr_ratio) / 0 <
{if}
(L.L.M_Wheel) (L.L.antrieb_getr_ratio) / (F.L.M_Wheel_schaltmoment) s0
{else}
(L.L.antrieb_kuppl_M_up_max)   s0
{endif}

   (L.L.engine_M) 0 <
{if}

(L.L.antrieb_beschleunigung) (L.L.antrieb_current_ratio) / (F.L.M_Wheel_schaltmoment)  s1
(L.L.antrieb_schaltmoment_soll)  s0

	(L.L.antrieb_getr_aktugang) 4 =
	{if}
		(L.L.engine_M) abs 1.1 * s0
	{endif}

{else}
500 s1

(C.L.antrieb_ecolife_class) 3 >
{if}

2000 s1

{endif}

{endif}



	(L.L.antrieb_getr_fest) !
	{if}
		(L.L.antrieb_schaltmoment) (L.S.Timegap) 500 * + (L.L.antrieb_schaltmoment_soll) min  (S.L.antrieb_schaltmoment)
	{endif}



'Fallunterscheidung, ob Getriebe reibt oder wandelt oder nicht:

	(L.L.antrieb_getr_fest)
	{if}

'#################################################################################
'	Berechnung der Beschleunigung des Antriebsstrangs (am Motorflansch) 
'     Calculate the acceleration of the drive train (on 'the flange)
'#################################################################################


		(L.L.n_Wheel) (L.L.antrieb_getr_ratio) * (L.L.engine_n) - 2 * pi * 60 / (L.S.Timegap) / 

'	Berechnung des Momentes am Motor durch Trägheit:

		(C.L.engine_J) * s0

'	Berechnung des vom Antriebsstrang durchgeleiteten Momentes

		l0 /-/ (L.L.engine_M) (L.L.engine_M_additional_load) - + s1


'	Wenn das Antriebsmoment zu groß ist oder ein Wandlergang eingelegt wird, rutscht die Kupplung durch:
'	If the torque is too large or a converter gear is engaged, the clutch slips:

		l1 abs (L.L.antrieb_schaltmoment) > (L.L.antrieb_getr_gangwahl) 1 <= || (L.L.antrieb_wandler_engage) 1 = || (L.L.brake) 0.5 > || 


		{if}

			0 (S.L.antrieb_getr_fest)

		{else}

'		Setzen des Momentes
'		Setting the torque

			l1 (S.L.antrieb_getr_M_an)


'		Berechnung des Getriebeabtriebmomentes:
'		Calculation of the transmission output torque:

			(L.L.antrieb_getr_M_an) (L.L.antrieb_getr_ratio) * (C.L.gear_efficiency) * (S.L.M_Wheel)

'		Drehzahl des Motors ergibt sich aus der Getriebeabtriebswelle:
'		Speed of the engine is obtained from the transmission output shaft:


			(L.L.antrieb_getr_ratio) (L.L.n_Wheel) * (S.L.engine_n)		
		{endif}


		0 (S.L.antrieb_wandler_moment)

	{else}

'#################################################################################
'	Bestimmen, ob Leerlauf ist...: Determine if idle ...:
'#################################################################################

		(L.L.antrieb_getr_gangwahl) 1 = (L.L.antrieb_getr_aktugang) 0 = ||

		{if}

'		... Antriebs- und Getriebeantriebsmoment sind 0:
			0 (S.L.M_Wheel) (S.L.antrieb_getr_M_an)

			(M.L.engine_acceleration)
			0 (S.L.antrieb_wandler_moment)

'			Wenn Neutralgang beim Bremsen eingelegt wird
			(L.L.antrieb_getr_gangwahl) 1 =
			{if}
				0 (S.L.antrieb_retarder_wasrunning) (S.L.antrieb_gear_engaged_timer)
			{endif}

		{else}

'#################################################################################
'		Bestimmen, ob ein Wandlergang eingelegt ist...: Determine whether a converter gear is engaged
'#################################################################################



	 (L.L.antrieb_wandler_engage) 1 = (L.L.engine_n) 550 < || (L.L.brake) 0.4 > ||   
		

			
			{if}

				(L.L.antrieb_wandler_moment) abs (L.L.antrieb_getr_M_an) abs >
				{if}
					(L.L.antrieb_wandler_moment) 0 >
					{if}
						(L.L.antrieb_getr_M_an) (C.L.antrieb_wandler_fillrate) (L.S.Timegap) * + (S.L.antrieb_getr_M_an)
						(L.L.antrieb_wandler_moment) (L.L.antrieb_getr_M_an) <
						{if}
							(L.L.antrieb_wandler_moment) (S.L.antrieb_getr_M_an)
						{endif}
					{else}
						(L.L.antrieb_getr_M_an) (C.L.antrieb_wandler_fillrate) (L.S.Timegap) * - (S.L.antrieb_getr_M_an)
						(L.L.antrieb_wandler_moment) (L.L.antrieb_getr_M_an) >
						{if}
							(L.L.antrieb_wandler_moment) (S.L.antrieb_getr_M_an)
						{endif}
					{endif}
				{else}
					(L.L.antrieb_wandler_moment) (S.L.antrieb_getr_M_an)
				{endif}
	
			

					(L.L.n_Wheel) (L.L.antrieb_getr_ratio) * s0 (S.L.antrieb_getr_n_ab) (L.L.engine_n) / (S.L.antrieb_wandler_ny)

					
'					Berechnung des Motor-Antriebsmomentes

					(L.L.engine_n) sqr l0 sqr - 1000 / 0.6 *  (L.L.engine_n) (F.L.antrieb_wandler_lowrpmsoftness) * (S.L.antrieb_wandler_moment)

'					Berechnung des Rad-Abtriebsmomentes
		
						(L.L.antrieb_wandler_ny) (F.L.antrieb_wandler_my) (L.L.antrieb_getr_M_an) * (L.L.antrieb_getr_ratio) * (L.L.engine_n) (F.L.antrieb_wandler_lowrpmsoftness) * (C.L.gear_efficiency) *  (S.L.M_Wheel) 
					

		

'			Vergleich der Ein- und Ausgangsleistungen:
				(L.L.M_Wheel) (L.L.n_Wheel) * 3.14 * 30000 / (S.L.antrieb_gesamtleistung)
				(L.L.antrieb_gesamtleistung) (L.L.antrieb_motorleistung) / (S.L.antrieb_eta)

	
				(M.L.engine_acceleration)

			



'#################################################################################
'			Sonst ist ein normaler Gang eingelegt:
'			Otherwise, a normal gear is engaged:
'#################################################################################

			{else}


'			Berechnung der Drehzahldifferenz:

				(L.L.antrieb_getr_ratio) (L.L.n_Wheel) * (L.L.engine_n) - s0


			

'			An dieser Stelle muss ggf. noch das unterschiedliche Kupplungsmoment eingesetzt werden:

				l0 0 <
				{if}
					(L.L.antrieb_schaltmoment)
				{else}
					(L.L.antrieb_schaltmoment) /-/
				{endif}
				(S.L.antrieb_getr_M_an)	 (L.L.engine_M) 1.15 * min  (L.L.engine_M) max
				(L.L.antrieb_getr_ratio) *
				(C.L.gear_efficiency) * (S.L.M_Wheel)


'	Berechnung der Drehzahlbeschleunigung:
' 	Calculation of speed acceleration:

	(L.L.engine_M) (L.L.antrieb_getr_M_an) (L.L.engine_M_additional_load) + - (C.L.engine_J) /

'	... Berechnung der Motordrehzahl anhand der Drehzahlbeschleunigung:

	(L.S.Timegap) * 30 * pi / (L.L.engine_n) + (S.L.engine_n)

'			Prüfen, ob sich das Vorzeichen der Drehzahldifferenz umgekehrt hat:

				(L.L.antrieb_getr_ratio) (L.L.n_Wheel) * (L.L.engine_n) - l0 * 0 <= (L.L.engine_n) 560 > &&
				{if}
					(L.L.antrieb_getr_ratio) (L.L.n_Wheel) * (S.L.engine_n)
					(L.L.n_Wheel) (L.L.antrieb_getr_ratio) * (L.L.engine_n) - 2 * pi * 60 / (L.S.Timegap) / 

'					Berechnung des Momentes am Motor durch Trägheit:

					(C.L.engine_J) * s0

'					Berechnung des vom Antriebsstrang durchgeleiteten Momentes

					l0 /-/ (L.L.engine_M) (L.L.engine_M_additional_load) - + (S.L.antrieb_getr_M_an)


'					Berechnung des Getriebeabtriebmomentes:
'					Calculation of the transmission output torque:

					(L.L.antrieb_getr_M_an) abs (L.L.antrieb_schaltmoment) abs <
					{if}
						(L.L.antrieb_getr_M_an) (L.L.antrieb_getr_ratio) * (C.L.gear_efficiency) * (S.L.M_Wheel)
						1 (S.L.antrieb_getr_fest)
						(M.L.input_torque_M_up_max) (S.L.antrieb_schaltmoment)
					{else}
						(L.L.antrieb_schaltmoment) /-/ (S.L.antrieb_getr_M_an) (L.L.antrieb_getr_ratio) * (C.L.gear_efficiency) * (S.L.M_Wheel)
					{endif}
					


				{endif}

				0 (S.L.antrieb_wandler_moment)

			{endif}
		{endif}

	{endif}







'#################################################################################
'	Retarder
'#################################################################################


	(L.L.brake) 0.01 >
	(L.L.antrieb_retarder_sw) &&
	(L.L.antrieb_retarder_sw_direkt) ||
	(L.L.antrieb_getr_gangwahl) 1 > &&
	(L.L.Throttle) 0.1 < &&
	(L.L.antrieb_kickdown_sense) 0.2 > &&
	(L.L.antrieb_n_kardanwelle) 0.1 > &&
	(L.L.antrieb_failure_general) ! &&
	(L.L.bremse_ABS_eingriff) ! &&
	{if}	

		(L.L.antrieb_retarder_armed) !
		{if}
			1 (S.L.antrieb_retarder_armed)
			0 (S.L.antrieb_retarder_armtime_elapsed)
		{endif}
	

		(L.L.antrieb_n_kardanwelle) (C.L.retarder_min_einschaltspeed) > (L.L.antrieb_retarder_armtime_elapsed) (C.L.antrieb_retarder_startdelay) > && (L.L.antrieb_retarder) ! && 
		{if}
			1 (S.L.antrieb_retarder)
			0 (S.L.antrieb_retarder_time_elapsed)
		{endif}


		(L.L.antrieb_retarder_sw_direkt) 
		{if}
			2 (S.L.antrieb_retarderstufe)
		{else}
			1 (S.L.antrieb_retarderstufe)
		{endif}

'Verhaltensweise des Retarders beim Erreichen der Drehzahluntergrenze im 2. Gang:

		(L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd2) < 
		(L.L.antrieb_retarder) 1 = &&
		{if}
			(C.L.antrieb_getr_version) s0 1 = l0 3 = ||
			{if}
				0 (S.L.antrieb_retarder) (S.L.antrieb_wendesatz)
				(L.L.engine_n) (S.L.antrieb_rucksoundvol)
			{else}
				0 (S.L.antrieb_getr_aktugang)
			{endif}
		{endif}
	

		(L.L.antrieb_retarder_armed)
		{if}
			(L.L.antrieb_retarder_armtime_elapsed) (L.S.Timegap) + (S.L.antrieb_retarder_armtime_elapsed)
			(L.L.antrieb_retarder_time_elapsed) (L.S.Timegap) + (S.L.antrieb_retarder_time_elapsed)
		{endif}

' Ausschalten des Retarders:

	{else}
		(L.L.antrieb_retarder) (L.L.antrieb_n_kardanwelle) (C.L.antrieb_getr_autoSwDnMinSpd2) < &&
		{if}
			0 (S.L.antrieb_retarder_offtime) (S.L.antrieb_wendesatz)
			1 (S.L.antrieb_retarder_wasrunning)
		{endif}
		0 (S.L.antrieb_retarder) (S.L.antrieb_retarder_armed) (S.L.antrieb_retarder_armtime_elapsed) (S.L.antrieb_retarder_time_elapsed)	
	{endif}

'Umschaltverzögerung zwischen Bremsen und Traktion:

	(L.L.antrieb_retarder_wasrunning)
	{if}
		(L.L.antrieb_retarder_offtime) (L.S.Timegap) + (S.L.antrieb_retarder_offtime) 
		(C.L.antrieb_retarder_changetime) >
		(L.L.antrieb_getr_gangwahl) 1 > &&
		{if}
			

'3424 soll hier laut rucken!
			(L.$.number) "3424" $=
			{if}
				900
			{else}
				(L.L.engine_n)
			{endif}
			(S.L.antrieb_rucksoundvol)
			0 (S.L.antrieb_retarder_wasrunning) (S.L.antrieb_gear_engaged_timer)
		{endif}
	{endif}

	

'Bremsmoment des Retarders:

	(L.L.antrieb_retarder) 1 =
	{if}
		1900 0.8 * 600 min (L.L.engine_n) 1900 / 1 min * (L.L.antrieb_retarder_time_elapsed) (F.L.retarder_fadein) * /-/ (S.L.antrieb_retardermoment) * 1000 min (C.L.gear_efficiency) * (C.L.antrieb_i_achse) * (L.L.M_Wheel) + (S.L.M_Wheel) 
	{else}
'		Ausfaden der Retarder-Bremsstärke
		(L.L.antrieb_retardermoment) (L.S.Timegap) 10000 * + 0 min (S.L.antrieb_retardermoment) (L.L.M_Wheel) + (S.L.M_Wheel)
		(L.L.antrieb_retarder_volume) (L.S.Timegap) 2 * - 0 max (S.L.antrieb_retarder_volume) s0
		l0 0 =
		{if}
			0 (S.L.antrieb_wendesatz)
		{endif}
	
	{endif}



'#################################################################################
'	Automatische Neutralschaltung bei Stillstand
'#################################################################################


(C.L.antrieb_getr_version) 1 >
{if}
	(L.L.antrieb_gear_engaged_timer) (L.S.Timegap) + (S.L.antrieb_gear_engaged_timer)
	(L.L.antrieb_n_kardanwelle) (C.L.antrieb_neutral_maxspeed) <
	(L.L.antrieb_getr_gangwahl) 1 > &&
	(L.L.antrieb_retarder) ! &&
	(L.L.antrieb_retarder_wasrunning) ! &&	
	{if}
		(L.L.bremse_p_Brzyl_HA) (C.L.antrieb_neutral_brakepressure) > 
		{if}
			(L.L.antrieb_neutral_requested) !
			{if}
				1 (S.L.antrieb_neutral_requested)

				(C.L.antrieb_getr_version) 2 = !
				(C.L.antrieb_getr_version) 2 = (L.L.antrieb_gear_engaged_timer) (C.L.antrieb_gear_engaged_mintime) < && ||
				{if}
					0 (S.L.antrieb_gear_engaged_timer)
				{endif}
			{endif}
			
			(L.L.antrieb_neutral_requested)
			(L.L.antrieb_gear_engaged_timer) (C.L.antrieb_gear_engaged_mintime) >= &&
			{if}
				0 (S.L.antrieb_getr_aktugang)
				0.3 (S.L.throttle_active)


				(L.L.antrieb_getr_gangwahl) 2 > (L.L.engine_on) &&
				{if}
				(L.L.antrieb_NBS) (L.S.Timegap) 1 * + 1 min (S.L.antrieb_NBS)
				{else}
				0 (S.L.antrieb_NBS)
				1 (S.L.throttle_active)
				{endif}
			{endif}
		   
		{else}	
			(L.L.antrieb_NBS) (L.S.Timegap) 1.5 * - 0 max (S.L.antrieb_NBS)
			1 (S.L.antrieb_getr_aktugang)
			
			
			0 (S.L.antrieb_neutral_requested) (S.L.antrieb_gear_engaged_timer)
			
		{endif}
		
	{endif}
{endif}










'#################################################################################
'	Planetengetriebe-Wendesatz (Fjü-Sound)
'#################################################################################
	
	(L.L.antrieb_retarder)  
	(L.L.antrieb_getr_gangwahl) 0 = ||
	{if}
		1 (S.L.antrieb_wendesatz) (S.L.antrieb_retarder_volume)
'		Rücksetzen auf 0 erfolgt beim Fadeout des Retarderbremsmoments
	{endif}
{end}



'#################################################################################
'	Bestimmung der Schaltgeschwindigkeiten
'#################################################################################

{macro:antrieb_getr_chkNxtGear}

'	Höchster Gang: s0!

'	Verzögerung der Kickdown-Schaltung:

	(L.L.throttle) 1 = (C.L.Kickdown_Enable) 1 = &&
	{if}						
		(L.L.antrieb_kickdown_stellglied) (L.S.Timegap) (C.L.kickdown_stellglied_inc_rate) * + 1 min (S.L.antrieb_kickdown_stellglied)
		1 =
		{if}
			1 (S.L.antrieb_kickdown)
		{endif}
	{else}
		(L.L.antrieb_kickdown_stellglied) (L.S.Timegap) (C.L.kickdown_stellglied_dec_rate) * - 0 max (S.L.antrieb_kickdown_stellglied)
		0 =
		{if}
			0 (S.L.antrieb_kickdown)
		{endif}
	{endif}

'	Verzögerung der gaspedalabhängigen Schaltschwelle:

	
	(L.L.throttle) (L.L.antrieb_throttle_stellglied) >
	{if}
		(L.L.antrieb_throttle_stellglied) (L.S.Timegap) (C.L.throttle_stellglied_inc_rate) * + (L.L.throttle) min (S.L.antrieb_throttle_stellglied)
	{else}
		(L.L.antrieb_throttle_stellglied) (L.S.Timegap) (C.L.throttle_stellglied_dec_rate) * - (L.L.throttle) max (S.L.antrieb_throttle_stellglied)
	{endif}
	
'	Berechnen der aktuellen Beschleunigung:
	
	(L.L.Velocity) (L.L.antrieb_last_geschwindigkeit) - 3.6 / (L.S.Timegap) / (S.L.antrieb_beschleunigung)
	(L.L.Velocity) (S.L.antrieb_last_geschwindigkeit)


     (L.L.M_wheel) (L.L.Velocity) 3.6 / (L.L.Velocity) 3.6 / * 9.5 0.55 0.6 * * * 1000 - - 10920 0.94 * / (S.L.beschleunigung_ratio)

	

	
'#################################################################################
'	Topodyno settings
'#################################################################################
(C.L.antrieb_topodyn_enable) (L.L.throttle) 0.1 > &&
 {if}
'	Calculate change in Throttle per second:
	
	(L.L.throttle) (L.L.antrieb_last_throttle) - 1 / (L.S.Timegap) / (S.L.antrieb_delta_throttle)
	(L.L.throttle) (S.L.antrieb_last_throttle)

'	smoothing out the acceleration to avoid rapid shifting point changes
	  (L.L.antrieb_beschleunigung) (L.L.antrieb_beschleunigung_last) >
	  {if}
		 (L.L.antrieb_beschleunigung_last) (L.S.Timegap) 10 * + 2 min (S.L.antrieb_beschleunigung_last)

	  {else}
		(L.L.antrieb_beschleunigung_last) (L.S.Timegap) 10 * - 0 max	(S.L.antrieb_beschleunigung_last)
	 {endif}


    
'F MA
' mass

 (L.L.antrieb_beschleunigung) 0 >  
{if}
(C.L.antrieb_topodyn_mass) (L.L.antrieb_beschleunigung) * (L.L.Velocity) 3.6 / (L.L.Velocity) 3.6 / * 9.5 0.5 0.6 * * * + 1000 + (C.L.antrieb_topodyn_sensitivity) * (S.L.antrieb_force)
{endif} 

 (L.L.antrieb_beschleunigung) 0 <
{if}
1 (S.L.antrieb_force)
{endif} 







(L.L.M_Wheel) (L.L.antrieb_force) / (S.L.antrieb_force_1)


	 (L.L.antrieb_force_1) (L.L.antrieb_force_2) > (L.L.engine_M) 300 > && (L.L.throttle) 0.2 > &&
	  {if}
		(L.L.antrieb_force_2) (L.S.Timegap) 0.4 * + 1 min (S.L.antrieb_force_2)

	  {else}
		(L.L.antrieb_force_2) (L.S.Timegap) 0.4 * - 0 max	(S.L.antrieb_force_2)
	 {endif}

		 

	 		 (L.L.antrieb_getr_aktugang) 1 =
	 {if}
	      1.91 s1

	{else}

			(L.L.antrieb_current_ratio) s1
	{endif}


'	Use throttle to calculate the correct acceleration  
	(L.L.Torque_Governor_set)
	 {if}
		 l1 (L.L.Torque_Governor_set) (L.L.Torque_Governor_ADJ) / * s8
	 {else}
		  l1  (L.L.Torque_Governor_ADJ) (L.L.Torque_Governor_ADJ) / * s8
	 {endif}

	 (L.L.velocity) 1 > 	    
	{if}				 
		(L.L.antrieb_kickdown_UpSpd) (L.L.antrieb_current_ratio) * (L.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_current_ratio) *  - s1  


		 (L.L.antrieb_force_2) (F.L.antrieb_force_2) l1 * (S.L.antrieb_topodyn_dn)


	{else}

		(L.L.antrieb_topodyn_dn) (L.S.Timegap) 400 * - 0 max (S.L.antrieb_topodyn_dn)
	{endif}

	 (L.L.velocity) 5 >
	 {if}

		 (L.L.antrieb_kickdown_DnSpd) (L.L.antrieb_current_ratio) * (L.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_current_ratio) * - s1


		  (L.L.antrieb_force_2) (F.L.antrieb_force_2) l1 * (S.L.antrieb_topodyn_Ups)

	
	{else}

			0 (S.L.antrieb_topodyn_Ups)
	{endif}




	
	(L.L.antrieb_topodyn_dn) (L.L.antrieb_current_ratio) / (S.L.antrieb_topodyn_factor) 

	(L.L.antrieb_topodyn_Ups) (L.L.antrieb_current_ratio) / (S.L.antrieb_topodyn_factor_Ups)

{else}
(L.L.antrieb_topodyn_Ups) (L.S.Timegap) 500 * - 0 max (S.L.antrieb_topodyn_Ups)
(L.L.antrieb_topodyn_dn) (L.S.Timegap) 500 * - 0 max (S.L.antrieb_topodyn_dn)
{endif}

'#################################################################################
'	Gearbox Controls
'#################################################################################




' coupling torque manauplator


	(C.L.antrieb_ecolife_class) 1 =
		{if}
			(C.L.antrieb_kuppl_M_up_max) (S.L.antrieb_kuppl_M_up_max)  
			{else}
				 (C.L.antrieb_ecolife_class) 2 =
				 {if}
					 (C.L.antrieb_kuppl_M_up_max_1) (S.L.antrieb_kuppl_M_up_max)  

					 {else}
					 (C.L.antrieb_ecolife_class) 3 =
						 {if}
							(C.L.antrieb_kuppl_M_up_max_2) (S.L.antrieb_kuppl_M_up_max)
							
							 {else}
							 	(C.L.antrieb_ecolife_class) 4 =
						 {if}
							(C.L.antrieb_kuppl_M_up_max_3) (S.L.antrieb_kuppl_M_up_max)
							 {else}
								(C.L.antrieb_ecolife_class) 5 =
						 {if}
							(C.L.antrieb_kuppl_M_up_max_4) (S.L.antrieb_kuppl_M_up_max)
						 {endif}
					        {endif}
						 {endif}
				 {endif}
		 {endif}





				(C.L.antrieb_ecolife_class) 1 =
					{if}
						(C.L.antrieb_kuppl_M_up_min) (S.L.antrieb_kuppl_M_up_min)
					{else}
					(C.L.antrieb_ecolife_class) 2 =
						 {if}
							(C.L.antrieb_kuppl_M_up_min_1) (S.L.antrieb_kuppl_M_up_min)

						 {else}
							 (C.L.antrieb_ecolife_class) 3 =
							{if}
								(C.L.antrieb_kuppl_M_up_min_2) (S.L.antrieb_kuppl_M_up_min)
								
						 {else}
							 (C.L.antrieb_ecolife_class) 4 =
							{if}
								(C.L.antrieb_kuppl_M_up_min_3) (S.L.antrieb_kuppl_M_up_min)
								
						 {else}
							 (C.L.antrieb_ecolife_class) 5 =
							{if}
								(C.L.antrieb_kuppl_M_up_min_4) (S.L.antrieb_kuppl_M_up_min)
								 {endif}
								  {endif}
							 {endif}
						 {endif}
					 {endif}




				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_dn_max) (S.L.antrieb_kuppl_M_dn_max)
						{else}
						 (C.L.antrieb_ecolife_class) 2 =
						 {if}
							 (C.L.antrieb_kuppl_M_dn_max_1)	(S.L.antrieb_kuppl_M_dn_max)

							 {else}
							  (C.L.antrieb_ecolife_class) 3 =
							  {if}
								(C.L.antrieb_kuppl_M_dn_max_2) (S.L.antrieb_kuppl_M_dn_max)

													 {else}
								  (C.L.antrieb_ecolife_class) 4 =
								  {if}
									(C.L.antrieb_kuppl_M_dn_max_3) (S.L.antrieb_kuppl_M_dn_max)

														 {else}
								  (C.L.antrieb_ecolife_class) 5 =
								  {if}
									(C.L.antrieb_kuppl_M_dn_max_4) (S.L.antrieb_kuppl_M_dn_max)
									 {endif}
								 {endif}
							 {endif}
						 {endif}
					 {endif}



					     
				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_dn_min) (S.L.antrieb_kuppl_M_dn_min)
					{else}
						(C.L.antrieb_ecolife_class) 2 =
						 {if}
							 (C.L.antrieb_kuppl_M_dn_min_1) (S.L.antrieb_kuppl_M_dn_min)

						 {else}
							(C.L.antrieb_ecolife_class) 3 =
							 {if}
							(C.L.antrieb_kuppl_M_dn_min_2) (S.L.antrieb_kuppl_M_dn_min) 

													 {else}
							(C.L.antrieb_ecolife_class) 4 =
							 {if}
							(C.L.antrieb_kuppl_M_dn_min_3) (S.L.antrieb_kuppl_M_dn_min) 

													 {else}
							(C.L.antrieb_ecolife_class) 5 =
							 {if}
							(C.L.antrieb_kuppl_M_dn_min_4) (S.L.antrieb_kuppl_M_dn_min) 
							 {endif}
							  {endif}
							 {endif}
						 {endif}
					 {endif}


  	(L.L.antrieb_getr_gangwahl) 0 =
	{if}
		-1 (S.L.antrieb_getr_aktugang)
	{endif}
		
	(L.L.antrieb_getr_gangwahl) 1 =
	{if}
		1 s0
	{endif}

	(L.L.antrieb_getr_gangwahl) 2 =
	{if}
		2 s0
	{endif}

	(L.L.antrieb_getr_gangwahl) 3 =
	{if}
		3 s0
	{endif}

	(L.L.antrieb_getr_gangwahl) 4 =
	{if}
		4 s0
	{endif}

	(L.L.antrieb_getr_gangwahl) 5 =
	{if}
		5 s0
	{endif}

	(L.L.antrieb_getr_gangwahl) 6 =
	{if}
		6 s0
	{endif}


		(L.L.antrieb_current_ratio) (L.L.antrieb_n_kardanwelle) * (S.L.antrieb_engine_n)

	 (L.L.antrieb_engine_n) (L.L.engine_n) / (S.L.antrieb_n_differenz_a)



			(L.L.antrieb_getr_aktugang) s1

			1 =
			{if}
				(C.L.antrieb_getr_ratio1) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)
				
			
			        (L.L.antrieb_kickdown)
				{if}
					(C.L.wandler1ockup_1_SwUpkickdn) s8 s9
				{else}
					(C.L.wandler1ockup_1_SwUpMaxSpd) s8
					(C.L.wandler1ockup_1_SwUpMinSpd) s9		
				{endif}


				(L.L.antrieb_is_downshift) 1 = (L.L.throttle) 0.1 > && (L.L.antrieb_is_downshift) (L.L.antrieb_n_kardanwelle) (C.L.wandler1ockup_1_SwDnMinSpd) < && ||
				{if}
					0 (S.L.antrieb_is_downshift)
				{endif}


				(M.L.antrieb_getr_chkCh1) (L.L.antrieb_n_kardanwelle) <	(L.L.antrieb_is_downshift) ! &&
				{if}
					0 (S.L.antrieb_wandler_engage)
	
					(M.L.input_torque_M_up_max) s6
					(M.L.input_torque_M_up_min) s7
					(M.L.antrieb_getr_schaltmoment) (S.L.antrieb_schaltmoment_soll) (S.L.antrieb_schaltmoment)
					
		
				{endif}

				(L.L.antrieb_kickdown)
				{if}
					(C.L.wandler1ockup_1_SwDnkickdn) s8 s9
				{else}

					(C.L.wandler1ockup_1_SwDnMaxSpd) s8
					(C.L.wandler1ockup_1_SwDnMinSpd) s9		
				{endif}
				
				(M.L.antrieb_getr_chkCh1) (L.L.antrieb_n_kardanwelle) > 
			     {if}
					1 (S.L.antrieb_wandler_engage)
				{endif}

				(L.L.antrieb_kickdown)  
				{if}
				
				(C.L.antrieb_getr_autoSwUpkickdnSpd1)  s3 s4
				
				{else}
					(C.L.antrieb_getr_autoSwUpMinSpd1)  s4
					(C.L.antrieb_getr_autoSwUpMaxSpd1) (S.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_topodyn_factor) + s3
				{endif}
				 (C.L.antrieb_getr_autoSwUpkickdnSpd1) (S.L.antrieb_kickdown_UpSpd) 
				
				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) < (L.L.antrieb_beschleunigung) 0 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > &&
				{if}

					(M.L.antrieb_throttlelimitor)
					2 (S.L.antrieb_getr_aktugang)

					 (L.L.engine_M) (L.L.antrieb_kuppl_M_up_min) max   (S.L.antrieb_schaltmoment)

					 (L.L.antrieb_kuppl_M_up_max) (S.L.antrieb_schaltmoment_soll)
	
				{endif}

			(L.L.antrieb_is_downshift)
			{if}
			
			{else}
			0 (S.L.antrieb_is_downshift)
			(M.L.antrieb_throttlegovernor_1)
			{endif}

			(M.L.antrieb_kickdown_time)

			
			
			
		
{endif}



			l1 -1 =
			{if}
				(C.L.antrieb_getr_ratioR) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)
			(M.L.antrieb_throttlegovernor_R)				
		
{endif}



l1 2 =
			{if}
				(C.L.antrieb_getr_ratio2) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)

			(L.L.antrieb_n_kardanwelle) 750 (L.L.antrieb_current_ratio) / >	(L.L.antrieb_kickdown_sense) 0.2 > &&
			{if}
				0 (S.L.antrieb_wandler_engage) 

			{endif}


			   
			(L.L.antrieb_n_kardanwelle) 650 (L.L.antrieb_current_ratio) / <
			{if}
			1 (S.L.antrieb_wandler_engage) 

			{endif}
				(L.L.antrieb_kickdown) 
				{if}
					
					(C.L.antrieb_getr_autoSwUpkickdnSpd2) s3 s4
						
				{else}
					(C.L.antrieb_getr_autoSwUpMinSpd2)  s4
					(C.L.antrieb_getr_autoSwUpMaxSpd2) (S.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_topodyn_factor) + s3		
				{endif}

				     (C.L.antrieb_getr_autoSwUpkickdnSpd2) (S.L.antrieb_kickdown_UpSpd)

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) < (L.L.antrieb_beschleunigung) (C.L.min_upshift_acceleration) > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && (L.L.throttle) 0.15 > &&
				{if}
					3 (S.L.antrieb_getr_aktugang)
					(M.L.antrieb_throttlelimitor)
					(M.L.input_torque_M_up_max) s6
					(M.L.input_torque_M_up_min) s7
					(M.L.antrieb_getr_schaltmoment) (S.L.antrieb_schaltmoment_soll) (S.L.antrieb_schaltmoment)
				{endif}
				
				
				(L.L.antrieb_kickdown)  
				{if}
					(C.L.antrieb_getr_autoSwDnkickdnSpd2) s3 s4
				{else}
					(C.L.antrieb_getr_autoSwDnMinSpd2) s4
					(C.L.antrieb_getr_autoSwDnMaxSpd2) (S.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_topodyn_factor_Ups) + s3
		
				{endif}
					(C.L.antrieb_getr_autoSwDnkickdnSpd2) (S.L.antrieb_kickdown_DnSpd)

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) > (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > &&
				{if}
					1 (S.L.antrieb_is_downshift)
					(M.L.antrieb_throttlelimitor_1)
					1 (S.L.antrieb_getr_aktugang)
					(M.L.input_torque_M_dn_max)  s6
					(M.L.input_torque_M_dn_min)  s7
					(L.L.engine_M)  (S.L.antrieb_schaltmoment)
					
				{endif}
					(L.L.antrieb_is_downshift) 	
					{if}

					1 s1
					{else}
					0.2 s1

					

					{endif}

						(M.L.antrieb_throttlegovernor_2)
						0 (S.L.antrieb_is_downshift)
				
		
			(M.L.antrieb_kickdown_time)

			{endif}
		

l1 3 =
			{if}
				(C.L.antrieb_getr_ratio3) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio) 


				(L.L.antrieb_kickdown) 
				{if}
					(C.L.antrieb_getr_autoSwUpkickdnSpd3)  s3 s4		
				{else}
					(C.L.antrieb_getr_autoSwUpMinSpd3)  s4
					(C.L.antrieb_getr_autoSwUpMaxSpd3) (S.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_topodyn_factor) + s3	
				{endif}

				       (C.L.antrieb_getr_autoSwUpkickdnSpd3) (S.L.antrieb_kickdown_UpSpd) 

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) < (L.L.antrieb_beschleunigung) (C.L.min_upshift_acceleration) > && (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && (L.L.throttle) 0.15 > && 
				{if}
		
					(M.L.antrieb_throttlelimitor)
					4 (S.L.antrieb_getr_aktugang)
					(M.L.input_torque_M_up_max)  s6
					(M.L.input_torque_M_up_min)  s7
					(M.L.antrieb_getr_schaltmoment) (S.L.antrieb_schaltmoment_soll) (S.L.antrieb_schaltmoment)
				
					
				{endif}



				(L.L.antrieb_kickdown)
				{if}
					(C.L.antrieb_getr_autoSwDnkickdnSpd3)  s3 s4
				{else}
					(C.L.antrieb_getr_autoSwDnMinSpd3) s4
					(C.L.antrieb_getr_autoSwDnMaxSpd3) (S.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_topodyn_factor_Ups) + s3
				{endif}
					(C.L.antrieb_getr_autoSwDnkickdnSpd3)	(S.L.antrieb_kickdown_DnSpd)

				(M.L.retarderdn)
				
				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) > (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > &&
				{if}	
					(M.L.antrieb_throttlelimitor_1)
					2 (S.L.antrieb_getr_aktugang)
					(M.L.antrieb_throttlelimitor_1)				
					(M.L.input_torque_M_dn_max) s6
					(M.L.input_torque_M_dn_min) s7
					(L.L.engine_M) abs (S.L.antrieb_schaltmoment)

					(L.L.engine_M)	0 >
					 {if}
					 
					   (L.L.engine_M) abs  (S.L.antrieb_schaltmoment) 
					 {endif}

				{endif}
				
				(L.L.antrieb_delta_throttle) 0.15 < 
				{if}
					(M.L.antrieb_kickdown_time1)
				{else}
					0 (S.L.antrieb_kickdown_sense1)
				{endif}			

				
	
					(L.L.antrieb_is_downshift) 	
					{if}

					1 s1
					{else}
					0.2 s1

					

					{endif}

						(M.L.antrieb_throttlegovernor_3)
						0 (S.L.antrieb_is_downshift)

			(M.L.antrieb_kickdown_time)
			
		
			{endif}




			l1 4 =
			{if}
				(C.L.antrieb_getr_ratio4) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)

				(L.L.antrieb_kickdown)
				{if}	
					(C.L.antrieb_getr_autoSwUpkickdnSpd4)   s3 s4	
				{else}
					(C.L.antrieb_getr_autoSwUpMinSpd4)  s4
					(C.L.antrieb_getr_autoSwUpMaxSpd4) (S.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_topodyn_factor) + s3

				{endif}
				
				       (C.L.antrieb_getr_autoSwUpkickdnSpd4) (S.L.antrieb_kickdown_UpSpd)

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) < (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_beschleunigung) (C.L.min_upshift_acceleration) > &&  (L.L.throttle) 0.15 > &&   
				{if}
					(M.L.antrieb_throttlelimitor)
					5 (S.L.antrieb_getr_aktugang)					
					(M.L.input_torque_M_up_max) s6
					(M.L.input_torque_M_up_min) s7
					(M.L.antrieb_getr_schaltmoment) (S.L.antrieb_schaltmoment_soll) (S.L.antrieb_schaltmoment)
				{endif}

				

			
				(L.L.antrieb_kickdown)   
				{if}
					(C.L.antrieb_getr_autoSwDnkickdnSpd4)  s3 s4	
				{else}
					(C.L.antrieb_getr_autoSwDnMinSpd4)  s4
					(C.L.antrieb_getr_autoSwDnMaxSpd4) (S.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_topodyn_factor_Ups) + s3
				{endif}
				
				 (C.L.antrieb_getr_autoSwDnkickdnSpd4)  (S.L.antrieb_kickdown_DnSpd)
			     	(M.L.retarderdn)
				

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) > (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && 
				{if}
					3 (S.L.antrieb_getr_aktugang)	
					(M.L.antrieb_throttlelimitor_1)				
					(M.L.input_torque_M_dn_max) s6
					(M.L.input_torque_M_dn_min) s7
					(L.L.engine_M) abs (S.L.antrieb_schaltmoment)
					
					(L.L.engine_M)	0 >
					 {if}
					
					   (L.L.engine_M) abs  (S.L.antrieb_schaltmoment) 
					 {endif}
				{endif}
	
					(L.L.antrieb_is_downshift) 	
					{if}

					1 s1
					{else}
					0.2 s1

					

					{endif}

						(M.L.antrieb_throttlegovernor_4)
						0 (S.L.antrieb_is_downshift)
				
				
		

			(L.L.antrieb_delta_throttle) 0.15 <
			{if}
				(M.L.antrieb_kickdown_time1)
			{else}
				0 (S.L.antrieb_kickdown_sense1)
			{endif}

			(M.L.antrieb_kickdown_time)
			{endif}


			l1 5 =
			{if}
				(C.L.antrieb_getr_ratio5) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)

				(L.L.antrieb_kickdown) 
				{if}
				
				(C.L.antrieb_getr_autoSwUpkickdnSpd5)  s3 s4
						
				{else}
					(C.L.antrieb_getr_autoSwUpMinSpd5) s4
					(C.L.antrieb_getr_autoSwUpMaxSpd5) (S.L.antrieb_getr_autoSwUpMaxSpd) (L.L.antrieb_topodyn_factor) + s3
					
				{endif}
				(C.L.antrieb_getr_autoSwUpkickdnSpd5) (S.L.antrieb_kickdown_UpSpd)

				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) < (L.L.antrieb_beschleunigung) (C.L.min_upshift_acceleration) > && (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && (L.L.throttle) 0.15 > && 
				{if}
					6 (S.L.antrieb_getr_aktugang) 
					(M.L.antrieb_throttlelimitor)
					(M.L.input_torque_M_up_max) s6
					(M.L.input_torque_M_up_min) s7
					(M.L.antrieb_getr_schaltmoment) (S.L.antrieb_schaltmoment_soll) (S.L.antrieb_schaltmoment)
				{endif}

				
				(L.L.antrieb_kickdown)
				{if} 
					(C.L.antrieb_getr_autoSwDnkickdnSpd5)  s3 s4
				{else}
					(C.L.antrieb_getr_autoSwDnMinSpd5)  s4
					(C.L.antrieb_getr_autoSwDnMaxSpd5) (S.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_topodyn_factor_Ups) + s3
				{endif}

				(C.L.antrieb_getr_autoSwDnkickdnSpd5)  (S.L.antrieb_kickdown_DnSpd)

				(M.L.retarderdn)
				
				
				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) > (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > &&
				{if}
					4 (S.L.antrieb_getr_aktugang)
					(M.L.antrieb_throttlelimitor_1)				
					(M.L.input_torque_M_dn_max) s6
					(M.L.input_torque_M_dn_min) s7
					(L.L.engine_M) abs  (S.L.antrieb_schaltmoment)


					(L.L.engine_M) 0 >
					 {if}
					
					   (L.L.engine_M) abs  (S.L.antrieb_schaltmoment) 
					 {endif}
				{endif}
 			(L.L.antrieb_delta_throttle) 0.15 <
			{if}
				(M.L.antrieb_kickdown_time1)
			{else}
				0 (S.L.antrieb_kickdown_sense1)
			{endif}

					(L.L.antrieb_is_downshift) 	
					{if}

					1 s1
					{else}
					0.2 s1

					

					{endif}

						(M.L.antrieb_throttlegovernor_5)
						0 (S.L.antrieb_is_downshift)
			
			
			(M.L.antrieb_kickdown_time)
			
	
			
			{endif}

			l1 6 =
			{if}
				(C.L.antrieb_getr_ratio6) (S.L.antrieb_current_ratio) (C.L.antrieb_i_achse) * (S.L.antrieb_getr_ratio)

				
				(L.L.antrieb_kickdown)
				{if}
					(C.L.antrieb_getr_autoSwDnkickdnSpd6)  s3 s4
				{else}
					(C.L.antrieb_getr_autoSwDnMinSpd6)  s4
					(C.L.antrieb_getr_autoSwDnMaxSpd6) (S.L.antrieb_getr_autoSwDnMaxSpd) (L.L.antrieb_topodyn_factor_Ups) + s3
				{endif}
				
				 (C.L.antrieb_getr_autoSwDnkickdnSpd6)  (S.L.antrieb_kickdown_DnSpd)

			       (M.L.retarderdn)


				(M.L.antrieb_getr_chkCh) (L.L.antrieb_n_kardanwelle) > (L.L.antrieb_kickdown_sense1) 0.5 > && (L.L.antrieb_kickdown_sense) (C.L.antrieb_hold_gear) > && 
				{if}
					5 (S.L.antrieb_getr_aktugang)
					(M.L.antrieb_throttlelimitor_1)
					 (M.L.input_torque_M_dn_max) s6
					 (M.L.input_torque_M_dn_min) s7
					

					  (L.L.engine_M) abs (S.L.antrieb_schaltmoment)
					(L.L.engine_M)	0 >
					 {if}
					
					   (L.L.engine_M) abs  (S.L.antrieb_schaltmoment) 
					 {endif}
					
				{endif}

					(L.L.antrieb_is_downshift) 	
					{if}

					1 s1
					{else}
					0.2 s1

					

					{endif}

						(M.L.antrieb_throttlegovernor_6)
						0 (S.L.antrieb_is_downshift)
				

				(M.L.antrieb_kickdown_time)
				
				

				 (L.L.antrieb_delta_throttle) 0.15 < 
				{if}
				(M.L.antrieb_kickdown_time1)
				{else}
					0 (S.L.antrieb_kickdown_sense1)
				{endif}

			{endif}


	{endif}
	{endif}



					 

'	Testweise: Differenzialdrehzahlpfeifen

	(L.L.engine_n) (L.L.antrieb_n_kardanwelle) 2 * - (S.L.antrieb_n_differenz)





{end}
{macro:partialthrottle_rate}
700 (S.L.Torque_Governor_set)

{end}
{macro:antrieb_getr_chkCh}
'	Berechnung der aktuellen Hochschaltschwelle: (l3 = bei Vollgas, l4 = bei Leergas)
	(L.L.antrieb_throttle_stellglied) (F.L.throttle_map) s2 l3 * 1 l2 - l4 * +
{end}

{macro:antrieb_getr_schaltmoment}
'	Berechnung des Schaltmomentes (l6 = bei Vollgas, l7 = bei Leergas)
	(L.L.antrieb_throttle_stellglied) s5 l6 * 1 l5 - l7 * +
{end}


{macro:antrieb_getr_schaltmomentshift}
'	Berechnung des Schaltmomentes (l6 = bei Vollgas, l7 = bei Leergas)
	(L.L.throttle) 0 > 
	{if}
		(M.L.input_torque_M_dn_max)
	{else}
		(L.L.antrieb_throttle_stellglied) s5 l6 * 1 l5 - l7 * +
	{endif}
	
{end}

{macro:antrieb_throttlelimitor}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
 0 (S.L.antrieb_kickdown_sense) 
{end}

{macro:antrieb_throttlelimitor_1}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
 0 (S.L.antrieb_kickdown_sense) 
 1 (S.L.antrieb_is_downshift)

{end}

{macro:antrieb_throttlegovernor_R}

(C.L.throttleinjection_governor_R) (S.L.Torque_Governor_set)
			
{end}

{macro:antrieb_throttlegovernor_1}

 (C.L.throttleinjection_governor_1) (S.L.Torque_Governor_set)
			
{end}


{macro:antrieb_throttlegovernor_2}
(L.L.antrieb_getr_fest) ! (L.L.antrieb_wandler_engage) ! &&
{if}

(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
{else}
 (C.L.throttleinjection_governor_2) (S.L.Torque_Governor_set)

 {endif}


{end}





{macro:antrieb_throttlegovernor_3}
 (L.L.antrieb_getr_fest) !  (L.L.antrieb_wandler_engage) ! &&
{if}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
{else}
  (C.L.throttleinjection_governor_3) (S.L.Torque_Governor_set)
 {endif}


 (L.L.antrieb_kickdown_sense) 0.3 >
{if}
0 (S.L.antrieb_wandler_engage)
{endif}

{end}

{macro:antrieb_throttlegovernor_4}
(L.L.antrieb_getr_fest) ! (L.L.antrieb_wandler_engage) ! &&
{if}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
{else}
  (C.L.throttleinjection_governor_4) (S.L.Torque_Governor_set)

 {endif}

  (L.L.antrieb_kickdown_sense) 0.3 >
{if}
0 (S.L.antrieb_wandler_engage)
{endif}

{end}


{macro:antrieb_throttlegovernor_5}
(L.L.antrieb_getr_fest) ! (L.L.antrieb_wandler_engage) ! &&
{if}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 	
  {else}
   (C.L.throttleinjection_governor_5) (S.L.Torque_Governor_set)

 {endif}

  (L.L.antrieb_kickdown_sense) 0.3 >
{if}
0 (S.L.antrieb_wandler_engage)
{endif}
{end}


{macro:antrieb_throttlegovernor_6}
(L.L.antrieb_getr_fest) ! (L.L.antrieb_wandler_engage) ! &&
{if}
(C.L.partial_throttleinjection_governor) (S.L.Torque_Governor_set) 
 {else}
  (C.L.throttleinjection_governor_6) (S.L.Torque_Governor_set)

 {endif}


{end}

{macro:input_torque_M_up_max}
				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_up_max)
					{else}
				 (C.L.antrieb_ecolife_class) 2 =
				 {if}
					 (C.L.antrieb_kuppl_M_up_max_1)

					 {else}
			          (C.L.antrieb_ecolife_class) 3 =
				  {if}
					(C.L.antrieb_kuppl_M_up_max_2)
					 {else}
			          (C.L.antrieb_ecolife_class) 4 =
				  {if}
					(C.L.antrieb_kuppl_M_up_max_3)
										 {else}
			          (C.L.antrieb_ecolife_class) 5 =
				  {if}
					(C.L.antrieb_kuppl_M_up_max_4)
					 {endif}
					 {endif}
					 {endif}
					 {endif}
					 {endif}

{end}


{macro:input_torque_M_up_min}
				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_up_min)
					{else}
				 (C.L.antrieb_ecolife_class) 2 =
				 {if}
					 (C.L.antrieb_kuppl_M_up_min_1)

					 {else}
			          (C.L.antrieb_ecolife_class) 3 =
				  {if}
					(C.L.antrieb_kuppl_M_up_min_2)
					 {else}
			          (C.L.antrieb_ecolife_class) 4 =
				  {if}
					(C.L.antrieb_kuppl_M_up_min_3)
										 {else}
			          (C.L.antrieb_ecolife_class) 5 =
				  {if}
					(C.L.antrieb_kuppl_M_up_min_4)
					 {endif}
					 {endif}
					 {endif}
					 {endif}
					 {endif}

{end}

{macro:input_torque_M_dn_max}
				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_dn_max)
					{else}
				 (C.L.antrieb_ecolife_class) 2 =
				 {if}
					 (C.L.antrieb_kuppl_M_dn_max_1)

					 {else}
			          (C.L.antrieb_ecolife_class) 3 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_max_2)
					 {else}
			          (C.L.antrieb_ecolife_class) 4 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_max_3)
										 {else}
			          (C.L.antrieb_ecolife_class) 5 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_max_4)
					 {endif}
					 {endif}
					 {endif}
					 {endif}
					 {endif}

{end}

{macro:input_torque_M_dn_min}
				(C.L.antrieb_ecolife_class) 1 =
					{if}
					(C.L.antrieb_kuppl_M_dn_min)
					{else}
				 (C.L.antrieb_ecolife_class) 2 =
				 {if}
					 (C.L.antrieb_kuppl_M_dn_min_1)

					 {else}
			          (C.L.antrieb_ecolife_class) 3 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_min_2)
					 {else}
			          (C.L.antrieb_ecolife_class) 4 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_min_3)
										 {else}
			          (C.L.antrieb_ecolife_class) 5 =
				  {if}
					(C.L.antrieb_kuppl_M_dn_min_4)
					 {endif}
					 {endif}
					 {endif}
					 {endif}
					 {endif}

{end}




{macro:antrieb_kickdown_time}
	(L.L.antrieb_kickdown_sense) (L.S.Timegap) 1 * + 10 min (S.L.antrieb_kickdown_sense)		
{end}



{macro:antrieb_brake_Dn}
	(L.L.antrieb_retarder_armed)
	{if}
		1000 (L.L.antrieb_current_ratio) / s4
	{endif}
{end}


 {macro:antrieb_kickdown_time1}

	(L.L.antrieb_kickdown_sense1) (L.S.Timegap) 1 * +  10 min (S.L.antrieb_kickdown_sense1)


	
{end}


{macro:antrieb_getr_chkCh1}
'	Berechnung der aktuellen Hochschaltschwelle: (l3 = bei Vollgas, l4 = bei Leergas)
	(L.L.antrieb_throttle_stellglied) s2 l8 * 1 l2 - l9 * +
{end}


{macro:retarderdn}
				(L.L.antrieb_retarder) (L.L.antrieb_kickdown_sense1) 0.25 > &&
				{if}


					(C.L.rpmdownshift_retarder_activated) s9


				l9 (L.L.antrieb_current_ratio) / s3 s4

				{endif}
{end}